// Spider:        fbd_spider.pov
//
// Delivered as fbd_spider_pov.txt for webservers.
//
// Render at 4:3 aspect ratio, e.g., 320 x 240 px
//
// Fudebakudo (c) Beholder 2003  www.beholder.co.uk
//--------------------------------------------------

#version 3.1;
#include "colors.inc"

global_settings
{
  assumed_gamma 1.0
}

camera
{
  location  <0, 5, -5> * 1.2
  direction z
  right     x
  look_at   <-0.66, 0.75,  0.0>
}

light_source
{
	0*x color rgb 1.0 area_light
	<4, 0, 0> <0, 0, 4> 8, 8                
	adaptive 0 jitter
	translate <60, 60, -3>
}

plane { y, 0 pigment {colour <116/255 0 0>}}

#declare spider =
	union
	{
		#macro leg (kneeJoint, foot)
			blob
			{
				threshold 0.5
				sphere{<0,0,0>, 1.5, 1.5}
				sphere{foot, 0.6, 0.6} 
				sphere{foot-y*0.5, 0.6, -0.6}                      
				cylinder{<0,0,0>,kneeJoint, 0.7, 0.7}
				cylinder{kneeJoint,foot,0.7, 0.7}
				//sturm
			}
			scale 0.25
			translate y*2.0
		#end
		
		sphere{0,1 scale <1,0.6,1> translate <-1,2,0>} // thorax        
		sphere{0,0.33 translate<0.5,2.5,0> } //head
		
		union
		{
			sphere{0, 0.15 translate <0.8, 2.6, -0.25>}
			sphere{0, 0.15 translate <0.8, 2.6,  0.25>}		
			pigment
			{
				gradient x
				color_map
				{
					[  0.0  White ]
					[  0.5  White ]
					[  0.5  Black ]
					[  1.0  Black ]
				} 
				scale 0.935 * 2
				translate y*2.6
			}
		}          
		object{leg(<5,4,0><10,-7,0>) translate x*0.33 rotate   45 * y }
		object{leg(<5,3,0><11,-7,0>) translate x*0.33 rotate   -45 * y }
		object{leg(<5,5,0><7.5,-7,0>) translate x*0.33 rotate   75 * y }
		object{leg(<5,5,0><7.5,-7,0>) translate x*0.33 rotate  -75 * y }
		object{leg(<5,4.5,0><8,-7,0>) translate x*0.33 rotate  105 * y }
		object{leg(<5,4.5,0><8,-7,0>) translate x*0.33 rotate -105 * y }
		object{leg(<6,3.0,0><10,-7,0>)  rotate  135 * y translate <0, 0 , -0.33>}
		object{leg(<6,2.5,0><12,-7,0>)  rotate -115 * y translate <0, 0, -0.33>}		
		pigment{White/8}  
		normal{wrinkles 0.9 scale 0.2}
		translate -y*0.2
	}

object{spider rotate 60*y}